#include "colors.inc"
global_settings {max_trace_level 256}

#declare c1=clock
#declare c2=clock+.5
#declare T1=texture {
  pigment {color rgb <0, 0, 1>}
  finish {phong 1}
  normal {crackle 2 scale .5}
}


// thigh
#declare t1=transform {
  rotate z*(180-40*cos(c2*2*pi))
  translate <0, 1.6+.6*abs(cos(c2*2*pi+.6)), .5>
}
// lower leg
#declare t2=transform {
  rotate z*(50-50*cos(c2*2*pi-.3))
  translate <0, 1.7, 0>
  t1
}
// foot
#declare t3=transform {
  rotate z*(-90-20*cos(c2*2*pi))
  translate <0, 1.5, 0>
  t2
}

blob { threshold .30
 
 cylinder {0, y*1.7, .35, 1 texture {T1} transform t1 }
 cylinder {0, y*1.3, .3, 1 texture {T1} transform t2}
 cylinder {0, y*.5, .3, 1 texture {T1} transform t3 }
// sturm
}


// thigh
#declare t1=transform {
  rotate z*(180-40*cos(c1*2*pi))
  translate <0, 1.6+.6*abs(cos(c2*pi*2+.6)), .5>
}
// lower leg
#declare t2=transform {
  rotate z*(50-50*cos(c1*2*pi-.3))
  translate <0, 1.7, 0>
  t1
}
// foot
#declare t3=transform {
  rotate z*(-90-20*cos(c1*2*pi))
  translate <0, 1.5, 0>
  t2
}

blob { threshold .30
 cylinder {0, y*1.7, .35, 1 texture {T1} transform t1 }
 cylinder {0, y*1.3, .3, 1 texture {T1} transform t2 }
 cylinder {0, y*.5, .3, 1 texture {T1} transform t3 }
// sturm
}

union {
  plane {z, 10 pigment {checker color White*.5 color White scale 3} }
  plane {y, -1.6 pigment {checker color White*.5 color White scale 3} }
  translate x*clock*12
}

light_source {<0, 100, -100> color White}

camera { location <0, 0, -5> right <340/240, 0, 0> look_at y*.4 angle 60 }